Using Aware Electronics Radiation Monitors and Software


A method to auto generate graphs using Aware Electronics Monitors and Windows software package Aw-Radw.

See bottom of this page for real time graphs made by-way-of the following information.
Note the following method uses two 16 bit programs, Aw-Graph.exe and Section.exe both included with the Aw-Radw software package. 64 bit Windows will not run 16 bit programs. Therefore for 64 bit Windows, use the procedure detailed here:
db_make_graphs.htm

Instructions below involve copying and pasting to batch files. When copying from an http file like this one, sometimes every line copied and pasted will have an extra space character at the end of the line which would disrupt the batch file execution. To avoid this, copy from the batch files found in this zip file (save zip to PC then unzip it):
make_graphs.zip

Note the make_graphs.zip contains a batch file named SETUP_GRAPH_DIRS.BAT. Assuming all your Aw-Radw files are in folder \AWARE, you could download the zip, unzip it to the same disk drive where you want to make the folders. etc., then run SETUP_GRAPH_DIRS.BAT which will make the folders mentioned below, and copy the default batch files and needed other files to the folders, at-which-point you could skip the following instructions that deal with making the folders, making the batch files START_RAD_DATA.BAT and MAKE_GRAPHS.BAT and copying the files. You could then right-click then edit the batch files, in-turn, to make any changes. You would still need to make the shortcuts, setup Aw-Radw and make the doftp.bat batch file as detailed below.


Method to auto generate gif image graphs of radiation data, assuming Aware Electronics Programs are in C:\AWARE and the binary radiation data files will be stored in C:\RAD_DATA and the graph images will be stored in C:\RAD_DATA\GRAPHS.

(You can use Windows Explorer to create new folders, copy files, create shortcuts etc. Start Windows Explorer by clicking: Windows "Start" button - "All Programs" - "Accessories" - "Windows Explorer")

1. Use Windows Explorer to make a folder on the PC named C:\RAD_DATA

2. In Windows Explorer click on RAD_DATA to change to that folder.

3. Click right mouse button then "New" - "Shortcut" then enter C:\AWARE\AW-RADW.EXE then type in for name "AW-RADW Shortcut" then click "Finish".

4. In Windows Explorer right click the shortcut "AW-RADW Shortcut" then click "Properties" then change "Start in:" to C:\RAD_DATA then click "OK"

5. Copy C:\AWARE\AW-RADW.SET to C:\RAD_DATA

6. Click the shortcut made in steps 3 and 4.

7. Aw-Radw starts. Click Aw-Radw menu item "Rad Options" and if need be, set all the various options, for example RM COM Port, Calibration Factor, and set the TBU to sixty seconds. Set "Rad Options" - "Default Message" to anything you want for example "My Office Location". If you plan to also generate ASCII files, set the Aw-Radw menu items under "Output Options" - "ASCII File Output Options". (See Aw-Radw help file).

Click Aw-Radw's "Exit" then "Quit Program" and Aw-Radw will then store all the menu item variables you set in C:\RAD_DATA\AW-RADW.SET then exit.

8. In Windows Explorer, with RAD_DATA as the current folder, click right mouse button then "New" - "Shortcut" then enter C:\AWARE\AW-GRAPH.EXE then type in for name "AW-GRAPH Shortcut" then click "Finish".

9. In Windows Explorer right click the shortcut "AW-GRAPH Shortcut" then click "Properties" then "Program" then change "Working:" to C:\RAD_DATA then click "OK"

10. Copy C:\AWARE\AW-GRAPH.SET to C:\RAD_DATA

11. Click the shortcut made in steps 8 and 9.

12. Aw-Graph starts. Use keyboard arrow keys to select Aw-Graph menu item "Make Graph"(then enter key) then "Aperture Size"(enter key) then replace what is there with 0 (zero) then enter key. Use arrow keys to select Aw-Graph menu item "Quit"(enter) then "Yes"(enter) then Aw-Graph asks "Save Setup" and select "Yes"(enter) and Aw-Graph exits saving the setup variables in the C:\RAD_DATA\AW-GRAPH.SET file. (Note you can use the Aw-Graph shortcut as above to change any of the other Aw-Graph variables, for example background colors, line colors, line styles, etc.).

13. In Windows Explorer, with C:\RAD_DATA as the current folder, right click the white area then click "New" then "Text Document" then rename it to "START_RAD_DATA.BAT".

14. Right click "START_RAD_DATA.BAT" then "Edit" then Windows Notepad starts.

15. Paste the following into the Notepad window:

@echo off
REM Batch file "START_RAD_DATA.BAT" for Startup Menu
setlocal
title Starting Aw-Radw

REM ***Add the location of the Aware programs to the path variable
set PATH=C:\AWARE;%PATH%

REM ************* JOIN THE CURRENT RAD FILE TO THE MASTER RAD FILE *****************************
if not exist ALLDATA.RAD copy CURRENT.RAD ALLDATA.RAD
if exist TEMP.RAD del TEMP.RAD
rename ALLDATA.RAD TEMP.RAD
start /SHARED /B /WAIT /MIN JOIN-RAD CURRENT.RAD TEMP.RAD ALLDATA.RAD
del CURRENT.RAD
if not exist ALLDATA.RAD rename TEMP.RAD ALLDATA.RAD
if exist TEMP.RAD del TEMP.RAD
rem sleep a little in case OS needs time to delete CURRENT.RAD
w-sleep 2

REM ************* Start Aw-Radw saving binary data to C:\RAD_DATA\CURRENT.RAD
start /min AW-RADW -LCURRENT.RAD -S

REM *** to start AW-RADW as above but also save the data to an ASCII file named C:\RAD_DATA\RAD_ASCII.TXT, use:
REM *** start /min AW-RADW -LCURRENT.RAD -aRAD_ASCII.TXT -S
REM *** Note for ASCII files, make sure you set Aw-Radw's menu items under "Output Options" - "ASCII Text File Options"

REM End of Batch file for Startup Menu

16. Save the above text in NotePad to C:\RAD_DATA\START_RAD_DATA.BAT

17. In Windows Explore, right click START_RAD_DATA.BAT then "Create Shortcut".

18. Right click the shortcut made in step 17 then "Copy".

19. Click Windows "Start" button, "All Programs" then right click "Startup" then "Explorer" then "Edit" then "Paste" which pastes the shortcut to C:\RAD_DATA\START_RAD_DATA.BAT in the Startup folder.

Now when Windows reboots for any reason, for example a power outage, when it starts again, Windows will automatically start Aw-Radw as per the C:\RAD_DATA\START_RAD_DATA.BAT batch file.

********End of info for startup menu

********Start of info to create the graphs

Now to auto make the graphs, assuming all the image files will be stored in C:\RAD_DATA\GRAPHS and assuming you know now how to use Windows Explorer and Windows NotePad as above:

1. Create the folder C:\RAD_DATA\GRAPHS

2. Create a new file MAKE_GRAPHS.BAT in the C:\RAD_DATA folder.

3. Place (copy-paste) the following to the file MAKE_GRAPHS.BAT and then save the file:

@echo off
setlocal
title Making Graphs
REM ***Add the location of the Aware programs to the path variable for this batch file
set PATH=C:\AWARE;%PATH%
REM
REM ***Set location of rad files.
REM set RAD_DIR=C:\RAD_DATA\ Don't need this because the batch file resides in C:\RAD_DATA so it is the current dir (folder)
REM
REM ***Set location for graph files
set GRAPH_DIR=C:\RAD_DATA\GRAPHS\
REM
REM ************* JOIN THE CURRENT RAD FILE TO THE MASTER RAD FILE *****************************
if not exist ALLDATA.RAD copy CURRENT.RAD ALLDATA.RAD
if exist TEMP.RAD del TEMP.RAD
rename ALLDATA.RAD TEMP.RAD
start /SHARED /B /WAIT /MIN JOIN-RAD CURRENT.RAD TEMP.RAD ALLDATA.RAD
if exist TEMP.RAD del TEMP.RAD
REM
REM ************* SET CONFIGURATION VARIABLES *******************************************
set TitleTag=My Radiation Data in Office
set XaxisTag=Date-Time (East Coast US)
REM
REM ***Set Y-axis Label and calb. for microR/hr standardized to Cesium 137
REM ***Note microR/hr calb for RM-60 is 105, calb for RM-70 is 149. calb for RM-80 is 354, calb for RM-G90 is 960
REM ***Also note the character will display as the micro character
set YaxisTag=RM-60 R/hr`
set calb=105
REM
REM ***Set Y-axis Label and calb. for microSv/hr standardized to Cesium 137
REM ***Note Sv/hr calb for RM-60 is 10500, calb for RM-70 is 14900. calb for RM-80 is 35400, calb for RM-G90 is 96000
REM set YaxisTag=RM-60 Sv/hr`
REM set calb=10500
REM
REM ***Set Y-axis Label and calb. for Counts per unit time. For example if TBU is 60 secs. then calb=0 displays CPM
REM set YaxisTag=RM-60 CPM`
REM set calb=0
REM
REM *** To have the Y-axis label equal the Y-Axis Caption entered when starting Aw-Radw collection of the rad. data,
REM *** enter a blank as in:
REM set YaxisTag=
REM
REM *** The size of the graph in x and y pixels:
set pixx=800
set pixy=400
REM
REM ****************************************** 6 HOUR GRAPH ************************************
DEL SE-1.RAD
SECTION -M360 ALLDATA.RAD
del 6-hr.rad
ren SE-1.RAD 6-hr.rad
set COMPRESS1=1
set COMPRESS2=15
set Curve1Tag=1 min. average
set Curve2Tag=15 min. average
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag% - PAST 6 HOURS`X%XaxisTag%`Y%YaxisTag%ARAY``D~~~
start /SHARED /B /WAIT /MIN aw-graph.exe -X100 -C%calb% -p%pixx% %pixy% -T -D6-hr.rad`%COMPRESS1%,6-hr.rad`%COMPRESS2% -k@
del 6-hr.rad
del %GRAPH_DIR%6-hr.gif
start /B /WAIT /MIN aw-radw.exe -Iawg.bmp -G%GRAPH_DIR%6-HR.GIF
del awg.bmp
REM
REM ****************************************** 1 DAY GRAPH ************************************
DEL SE-1.RAD
SECTION -M1440 ALLDATA.RAD
del 24-hr.rad
ren SE-1.RAD 24-hr.rad
set COMPRESS1=5
set COMPRESS2=60
set Curve1Tag=5 min. average
set Curve2Tag=60 min. average
REM
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag% - PAST 24 HOURS`X%XaxisTag%`Y%YaxisTag%ARAY``D~~~
start /SHARED /B /WAIT /MIN aw-graph.exe -X100 -C%calb% -p%pixx% %pixy% -T -D24-hr.rad`%COMPRESS1%,24-hr.rad`%COMPRESS2% -k@
del 24-hr.rad
del %GRAPH_DIR%24-hr.gif
start /B /WAIT /MIN aw-radw.exe -Iawg.bmp -G%GRAPH_DIR%24-HR.GIF
del C:\RAD_DATA\awg.bmp
REM
REM ****************************************** 7 DAY GRAPH ************************************
DEL SE-1.RAD
SECTION -M10080 ALLDATA.RAD
del 7-day.rad
ren SE-1.RAD 7-day.rad
set COMPRESS1=15
set COMPRESS2=180
set Curve1Tag=15 min. average
set Curve2Tag=3 hour average
REM
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag% - PAST 7 DAYS`X%XaxisTag%`Y%YaxisTag%ARAY``D~~~
start /SHARED /B /WAIT /MIN aw-graph.exe -X100 -C%calb% -p%pixx% %pixy% -T -D7-day.rad`%COMPRESS1%,7-day.rad`%COMPRESS2% -k@
del 7-day.rad
del %GRAPH_DIR%7-day.gif
start /B /WAIT /MIN aw-radw.exe -Iawg.bmp -G%GRAPH_DIR%7-DAY.GIF
del C:\RAD_DATA\awg.bmp
REM
REM **************************************** 28 DAY GRAPH *******************************************
DEL SE-1.RAD
SECTION -M40320 ALLDATA.RAD
del 28-day.rad
ren SE-1.RAD 28-day.rad
set COMPRESS1=60
set COMPRESS2=360
set Curve1Tag=1 hour average
set Curve2Tag=6 hour average
REM
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag% - PAST 28 DAYS`X%XaxisTag%`Y%YaxisTag%ARAY``D~~~
start /SHARED /B /WAIT /MIN aw-graph.exe -X100 -C%calb% -p%pixx% %pixy% -T -D28-day.rad`%COMPRESS1%,28-day.rad`%COMPRESS2% -k@
del 28-day.rad
del %GRAPH_DIR%28-day.gif
start /B /WAIT /MIN aw-radw.exe -Iawg.bmp -G%GRAPH_DIR%28-DAY.GIF
del C:\RAD_DATA\awg.bmp
REM
REM **************************************** 365 day GRAPH *******************************************
DEL SE-1.RAD
SECTION -M525600 ALLDATA.RAD
del 365-day.rad
ren SE-1.RAD 365-day.rad
set COMPRESS1=240
set COMPRESS2=1440
set Curve1Tag=4 hour average
set Curve2Tag=1 day average
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag% - PAST 365 DAYS`X%XaxisTag%`Y%YaxisTag%ARAY``D~~~
start /SHARED /B /WAIT /MIN aw-graph.exe -X100 -C%calb% -p%pixx% %pixy% -T -D365-day.rad`%COMPRESS1%,365-day.rad`%COMPRESS2% -k@
del 365-day.rad
del %GRAPH_DIR%365-day.gif
start /B /WAIT /MIN aw-radw.exe -Iawg.bmp -G%GRAPH_DIR%365-DAY.GIF
del C:\RAD_DATA\awg.bmp
del se-1.rad
REM
REM ****************************************Change to the graphs folder and call doftp.bat
cd %GRAPH_DIR%
call doftp.bat
exit
REM ***************End of MAKE_GRAPHS.BAT**********************************************************

********Start of info to ftp the graphs to a website

Notice the last part of the above MAKE_GRAPHS.BAT file changes to the folder C:\RAD_DATA\GRAPHS and then calls the batch file doftp.bat. There are many ways to auto ftp files to a website. Next we will create doftp.bat containing windows commands to ftp the files:

1. Create a new file doftp.bat in the C:\RAD_DATA\GRAPHS folder

2. Place (copy-paste) the following to the file C:\RAD_DATA\GRAPHS\doftp.bat and then save the file:

ftp -i -s:ftplist.txt
if errorlevel 1 ftp -i -s:ftplist.txt

3. Save the file C:\RAD_DATA\GRAPHS\doftp.bat

4. Create a new file ftplist.txt in the C:\RAD_DATA\GRAPHS folder

5. Place (copy-paste) the following to the file C:\RAD_DATA\GRAPHS\ftplist.txt and then save the file:

open mywebsite.com
username
password
binary
put C:\RAD_DATA\GRAPHS\6-hr.gif 6-hr.gif
put C:\RAD_DATA\GRAPHS\24-hr.gif 24-hr.gif
put C:\RAD_DATA\GRAPHS\7-day.gif 7-day.gif
put C:\RAD_DATA\GRAPHS\28-day.gif 28-day.gif
put C:\RAD_DATA\GRAPHS\365-day.gif 365-day.gif
bye

Replace the above mywebsite.com with your website's ftp server name which most often is the website address without the www.

Replace username with your ftp username which most often is along the lines of username.mywebsite.com

Replace password with your ftp password.

**********Setting Aw-Radw to run the MAKE_GRAPHS.BAT file

1. From Windows Explorer, in the C:\RAD_DATA folder, click on the shortcut you made to start Aw-Radw.

2. Click Aw-Radw menu "Output Options" - "Trigger a Program Every X Points" - "Trigger Program Yes-No" -"Trigger Program Minimized".

3. Click Aw-Radw menu "Output Options" - "Trigger a Program Every X Points" - "Choose Trigger Program" and enter MAKE_GRAPHS.BAT

4. Click Aw-Radw menu "Output Options" - "Trigger a Program Every X Points" - "Commandline Argument for Trigger Program" and erase anything there.

5. Click Aw-Radw menu "Output Options" - "Trigger a Program Every X Points" - "Choose # of Points per Trigger" and enter 10.

6. Exit Aw-Radw.

That's it. To test your setup and start collecting, click the C:\RAD_DATA\START_RAD_DATA.BAT or the shortcut link you made in the Startup folder and Aw-Radw should startup, collecting the rad data to CURRENT.RAD and every ten minutes it will trigger the MAKE_GRAPHS.BAT file.

Notes: The program JOIN-RAD.EXE should be in your C:\AWARE folder. It might be in a zip file within C:\AWARE i.e. C\AWARE\join-rad.zip in-which-case use Windows Explorer to click on C\AWARE\join-rad.zip, right click join-rad.exe then paste it to C:\AWARE.

Section.exe and Aw-Graph.exe are 16 bit programs which might not run under 64 bit versions of Windows, in-which-case one can use AW-DB.EXE to run Section.exe and Aw-Graph.exe. For more information E-Mail Bryan at boardmanb@aw-el.com


Actual Real-Time Graphs Using Above Technique

6 Hour Graph

Radon Fleas in Basement


24 Hour Graph

Radon Fleas in Basement


7 Day Graph

Radon Fleas in Basement


28 Day Graph

Radon Fleas in Basement


365 Day Graph

Radon Fleas in Basement


E-mail aware@aw-el.com
Phone:(800)729-5397 or Phone/Fax: (302)655-3800